load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
;********************************************
; read in data
;********************************************
  f = addfile("fvgcm_amr.delp.000240.000.nc","r")
  H = f->H     ; one dimensional
;********************************************
; create plot
;********************************************
  wks = gsn_open_wks("ps","adapt")
  gsn_define_colormap(wks,"BlAqGrYeOrReVi200")

  res                       = True            ; plot mods desired
;  res@gsnMaximize           = True           ; largest plot possible
  res@gsnSpreadColors       = True            ; use full range of colormap

  res@cnFillOn              = True            ; turn on color
  res@cnLinesOn             = False           ; no contour lines
  res@cnLineLabelsOn        = False           ; no line labels
;  res@cnVerboseTriangleInfo = True           ; prints out triangular mesh info

  res@lbLabelAutoStride     = True            ; nice stride on label bar

  res@tiMainString          = "Adaptive grid using triangular mesh conversion"

; these two resources are required to "enable" the triangular mesh function 
; when the input data is one-demensional
  res@sfXArray              = f->lon          ; assign lat/lon
  res@sfYArray              = f->lat

  map = gsn_csm_contour_map_ce(wks,H,res)
end