;*************************************************
; NCL Graphics: color_9.ncl
;;************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"    
;************************************************
begin
;**************************
; merge the colormaps
;**************************
  wks = gsn_open_wks("ps","color")               ; open a ps file

  gsn_merge_colormaps(wks,"wgne15","gui_default") ; merge two color maps
 
  gsn_draw_colormap(wks)                          ; draw color map
;**************************
; now use them in a panel situation
;************************** 
  a = addfile("uv300.nc","r")
  u = a->U(1,:,:)                    ; read in data

  plot = new(2,graphic)              ; create graphic array for panel plot

  res           = True               ; plot mods desired
  res@cnFillOn  = True               ; turn on color fill
  res@gsnDraw   = False              ; don't draw yet
  res@gsnFrame  = False              ; don't advance frame yet

  res@gsnSpreadColors     = True     ; use full color map
  res@gsnSpreadColorStart = 4        ; start at 4
  res@gsnSpreadColorEnd   = 15       ; end at 15

  res@cnLevelSpacingF = 6.           ; contour levels 
  plot(0) = gsn_csm_contour_map_ce(wks,u, res)    

  res@cnLevelSpacingF     = 5.       ; change contour spacing
  res@gsnSpreadColorStart = 17       ; now start at color 17
  res@gsnSpreadColorEnd   = 40       ; and end at color 40
  plot(1) = gsn_csm_contour_map_ce(wks,u, res)    

  gsn_panel(wks,plot,(/2,1/),False)
end