load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl" 
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl" 

begin
  f      = addfile ("b003_T_200-299.nc", "r")
  x      = f->T(:,17,:,:)       ; Grab lowest sigma level (=17)
  newx   = x(lat|:,lon|:,time|:)			; done to carry over coordinate variables, attributes
  newx	 = (/ dim_rmvmean(x(lat|:,lon|:,time|:)) /)
  delete(x)

  wks = gsn_open_wks("ps","conLev_3")
  gsn_define_colormap(wks,"BlWhRe")	     ; use the BlWhRe colormap (instead of default colormap)
  color1 = NhlNewColor(wks,0.75,.75,0.75)   ; add a lighter gray to the color map

  res             = True
  res@mpFillOn    = False						; turn map fill off
  res@mpOutlineOn = True						; turn the map outline on
  res@cnLevelSelectionMode = "ExplicitLevels"    			; set explicit contour levels
  res@cnLevels    = (/ -10.,-8.,-6.,-4.,-2.,-1.,1.,2.,4.,6.,8.,10./)	; set levels
  res@cnFillOn    = True		   				; turn on color fill
  res@cnLinesOn   = False		   				; turn off the contour lines
  res@cnFillColors = (/ 13,23,30,36,41,45,-1,59,63,68,74,81,91/)	; set the colors to be used
  res@cnLineLabelsOn = False						; turn the line labels off
  plot = gsn_csm_contour_map_ce(wks,newx(:,:,0),res)    
end