;
; conOncon_3.ncl
;
;*************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
begin

  a = addfile("uv300.nc","r")

  u = a->U(0,:,:) ; this includes the cyclic point
  v = a->V(0,:,:) ; this includes the cyclic point

  wks = gsn_open_wks("ps" ,"conOncon")
  gsn_define_colormap(wks,"blwhre")

;*****************************
; create first plot
;*****************************
  resn            = True 	; create vector resource array
  resn@gsnPolarNH = True	; choose northern hemisphere
  resn@cnFillOn   = True	; color fill
  resn@cnLinesOn  = False	; no contour lines

  resn@gsnDraw    = False	; don't draw
  resn@gsnFrame   = False	; don't advance frame

  resn@gsnSpreadColors     = True ; spread out color table

  plot1 = gsn_csm_contour_map_polar(wks,u,resn)
;*****************************
; create second plot
;*****************************
  res = True
  res@gsnTickMarksOn   = False	; no tickmarks
  res@gsnDraw          = False	; don't draw
  res@gsnFrame         = False	; don't advance frame
  res@gsnLeftString    = ""	; no titles
  res@gsnRightString   = ""
  res@tiXAxisString    = ""
  res@tiYAxisString    = ""
  res@cnLineThicknessF = 1.5	; thicker contours
  res@cnLineLabelsOn   = False	; no line labels

  plot2 = gsn_csm_contour(wks,v,res)
;******************************
; overlay the plots
;******************************
  overlay(plot1,plot2)
  draw(plot1)
  frame(wks)
end