;***********************
; coneff_11.ncl
;***********************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
;===========================
begin
;*************************
; get data
;*************************
 f     = addfile("atmos.nc","r") 
 u     = f->V(0,0,:,:)       
;===========================
; plot parameters
;===========================
 wks   = gsn_open_wks ("ps", "coneff" )     ; open workstation
 res                      = True             ; plot mods desired
 res@cnFillOn             = True             ; fill contour intervals
 res@lbLabelAutoStride    = True             ; nice label bar stride

 res@cnLevelSelectionMode = "ManualLevels"   ; manually specify contour levels
 res@cnMinLevelValF       = -35.             ; min level
 res@cnMaxLevelValF       =  35.             ; max level
 res@cnLevelSpacingF      =  10              ; contour interval

 res@cnMonoFillPattern    = False            ; want multiple patterns 
 res@cnFillPatterns       = (/3,3,3,3,-1,17,17,17,17/) ; the patterns
 res@cnMonoFillScale      = False            ; want different densities 
 res@cnFillScales         = (/.1,.2,.3,.4,1,1,1.5,2.0,2.5/) ; the densities

 res@tiMainString         = "Default dot size"
 plot = gsn_csm_contour(wks, u, res ) 
                    
; second plot. increase the size of the stipling dot pattern (#17). Note
; that you have to set it for the label bar as well.         
 res@cnFillDotSizeF       = 0.005            ; increase dot size of contours
 res@tiMainString         = "Increased to 0.005"
 plot = gsn_csm_contour(wks, u, res ) 
end