;***********************
; conwomap_5.ncl
;
; Concepts illustrated:
;   - Drawing a simple contour plot
;   - Making an axis logarithmic in a contour plot
;   - Changing the labels and tickmarks on a contour plot
;   - Creating a main title
;   - Attaching coordinate arrays to a variable
;
;***********************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
;===========================
begin
;*************************
; get data
;*************************
 f     = addfile("atmos.nc","r") 
 u     = f->U(0,:,:,:)       
;*************************
; convert to pressure levels
;*************************
  hyam   = f->hyam
  hybm   = f->hybm
  ps     = f->PS 
  p0     = 1000.
  pres3d      = (/1000,950,800,700,600,500,400,300,200/)
  pres3d@units= "mb"

  uint=(/vinth2p(u,hyam,hybm,pres3d,ps(0,:,:),2,\
              p0,2,False)/)
  uint!0    = "plev"
  uint&plev = pres3d
  uint!1    = "lat"
  uint&lat  = u&lat
  uint!2    = "lon"
  uint&lon  = u&lon
  uint@long_name = "Zonal Wind"
 
  uzon=uint(:,:,0)
  uzon=dim_avg(uint)
 
;===========================
; plot parameters
;===========================
 wks   = gsn_open_wks ("ps", "conwomap" )         ; open workstation

 res               = True            ; Plot mods desired
 res@gsnMaximize   = True            ; Maximize plot in frame

 res@tiMainString  = "Linear axis"   ; Main title

 plot = gsn_csm_contour(wks, uzon, res ) 

 res@tiMainString          = "Logarithmic axis"

 res@gsnYAxisIrregular2Log = True   ; Convert Y axis to logarithmic

; Set some axis labels, otherwise all we'll get is "10^3".
 res@tmYLMode              = "Explicit"
 res@tmYLValues            = (/300,500,700,1000/)
 res@tmYLLabels            = "" + res@tmYLValues

 plot = gsn_csm_contour(wks, uzon, res ) 
end