;*****************************************************
; cru_2.ncl
;*****************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"  
;*****************************************************
begin
;*****************************************************
; Read Absolute temperatures for the base period 1961-90
; data are stored as type "short" ... convert to float
;***************************************************
  f    = addfile("absolute.nc","r")
  T    = short2flt( f->tem )                          ; contributed.ncl
  T@long_name = "Temperature"          ; change value original too long
;***************************************
; create individual plots
;***************************************  
  wks = gsn_open_wks("ps","cru")                ; open ps file
  gsn_define_colormap(wks,"gui_default")        ; choose colormap
  plot = new(2, graphic)                        ; create graphical array

  res                      = True               ; plot mods desired

  res@cnFillOn             = True               ; color contours
  res@cnLinesOn            = False              ; default is True
  res@cnLineLabelsOn       = False              ; default is True
  res@gsnSpreadColors      = True               ; use full range of colormap

  res@gsnDraw              = False              ; don't draw yet
  res@gsnFrame             = False              ; don't advance frame yet

  res@gsnCenterString      = "February"
  plot(0)  = gsn_csm_contour_map_ce(wks,T(1,:,:),res)
  res@gsnCenterString      = "August"
  plot(1)  = gsn_csm_contour_map_ce(wks,T(7,:,:),res)

; create panel plot
  gsn_panel(wks,plot,(/2,1/),False)
end