load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
  wks  = gsn_open_wks("ps","maponly")              ; open a ps file

  res                = True              ; plot mods desired

  res@mpMinLatF      = 34.			 ; select region to be plotted
  res@mpMaxLatF      = 43.		      ; (Greece)
  res@mpMinLonF      = 19.
  res@mpMaxLonF      = 28.
  res@gsnDraw        = False             ; don't draw the plots
  res@gsnFrame       = False             ; don't advance the frame
  res@tmYROn         = False
  res@tmXTOn         = False
  
  yres = True                            ; panel resource list
  yres@gsnMaximize = True                ; maximize the plots
  yres@gsnPanelYWhiteSpacePercent = 5.0  ; increase white space between panels in y-direction
  
  map = new(3,graphic)
  res@mpDataBaseVersion = "LowRes"       ; select the low resolution database
  res@gsnCenterString = "Ncarg4_0/LowRes Database"
  map(0) = gsn_csm_map_ce(wks,res)
  
  res@mpDataBaseVersion = "MediumRes"     ; select the medium resolution database
  res@gsnCenterString = "Ncarg4_1/MediumRes Database"
  map(1) = gsn_csm_map_ce(wks,res)
  
  res@mpDataBaseVersion = "HighRes"       ; select the high resolution database
  res@gsnCenterString = "RANGS/HighRes Database"
  map(2) = gsn_csm_map_ce(wks,res)
  gsn_panel(wks,map,(/2,2/),yres)
end