;*************************************************
; mask_1.ncl
;************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"  
;************************************************
begin
;************************************************
; read in netCDF file
;************************************************
  in = addfile("atmos.nc","r")
  ts = in->TS(0,:,:)
  oro = in->ORO(0,:,:)

;************************************************
; use mask function to mask out land and then ocean data
; ocean=0,land=1,sea_ice=2
;************************************************
  land_only  = ts                               ; trick to keep cv's and atts
  ocean_only = ts

  land_only  = mask(ts,oro,1)
  ocean_only = mask(ts,oro,0)

;************************************************
; common resources
;************************************************
  wks = gsn_open_wks("ps","mask")                  ; open a ps file
  gsn_define_colormap(wks,"BlAqGrYeOrRe")           ; choose colormap


  res                      = True     ; plot mods desired
  res@cnFillOn             = True     ; turn on color fill
  res@cnLinesOn            = False    ; turn of contour lines

  res@gsnSpreadColors      = True     ; use full colormap
  res@gsnSpreadColorStart  = 10       ; start at color 10
  res@gsnSpreadColorEnd    = 96       ; end at color 96
;************************************************
; individual plots
;************************************************
  res@cnLevelSpacingF         = 3                ; interval
  res@lbLabelStride           = 4                ; every 4th label
  res@tiMainString            = "Land Only"      ; title
  plot = gsn_csm_contour_map_ce(wks,land_only,res)

  res@cnLevelSpacingF         = 2                ; interval
  res@lbLabelStride           = 2                ; every 2nd label
  res@tiMainString            = "Ocean Only"     ; title
  plot = gsn_csm_contour_map_ce(wks,ocean_only,res) 
end