load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"  
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"  

begin
  f       = addfile ("/project/cas/shea/GRIB/merged_AWIP32.1979010100.3D.NARR.grb", "r")
  lat2d   = f->gridlat_221
  lon2d   = f->gridlon_221
  dimlc   = dimsizes(lat2d)
  nlat    = dimlc(0)
  mlon    = dimlc(1)
  x       = f->U_GRD_221_ISBL              ; (lev,lat,lon)    
;*************create plots*******************
  wks  = gsn_open_wks ("ps", "narr")          ; open workstation  
  gsn_define_colormap (wks,"gui_default")         ; choose color map
  
  res                        = True               ; plot mods desired for original grid
  res@cnFillOn               = True               ; color fill  
  res@cnLinesOn              = False              ; no contour lines
  res@gsnSpreadColors        = True               ; use total colormap
  res@gsnSpreadColorStart    = 4 
  res@gsnSpreadColorEnd      = -1   
  res@mpGridAndLimbOn        = True
  res@pmTickMarkDisplayMode  = "Always"           ; turn on tickmarks
  res@tmXTOn                 = False  
  res@gsnAddCyclic           = False              ; regional data

  res@mpLimitMode            = "Corners"            ; choose range of map
  res@mpLeftCornerLatF       = lat2d(0,0)
  res@mpLeftCornerLonF       = lon2d(0,0)
  res@mpRightCornerLatF      = lat2d(nlat-1,mlon-1)
  res@mpRightCornerLonF      = lon2d(nlat-1,mlon-1)
  res@tfDoNDCOverlay         = True  
  res@mpProjection           = "LambertConformal" 
  res@mpLambertParallel1F    = lat2d@mpLambertParallel1F
  res@mpLambertParallel2F    = lat2d@mpLambertParallel2F
  res@mpLambertMeridianF     = lat2d@mpLambertMeridianF

  res@gsnCenterString         = "U@"+x&lv_ISBL0(10) + "hPa"		; draw center subtitle
  res@gsnLeftString           = "Original grid"				; draw left subtitle
  plot = gsn_csm_contour_map(wks,x(10,:,:),res)     			; Draw original grid on map
  end