;*************************************************
; panel_1.ncl
;************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
;************************************************
begin
;************************************************
; read in netCDF file
;************************************************
  a = addfile("uv300.nc","r")
  u = a->U(1,:,:)                                ; read July zonal winds
  v = a->V(1,:,:)
;************************************************
; create plots
;************************************************
  wks = gsn_open_wks("ps","panel")               ; open a ps file
  plot = new(3,graphic)                          ; create a plot array
  
  res          = True
  res@gsnDraw  = False                          ; don't draw
  res@gsnFrame = False                          ; don't advance frame
  res@cnInfoLabelOn = False                     ; turn off cn info label

  plot(0) = gsn_csm_contour_map_ce(wks,u,res) 
  plot(1) = gsn_csm_contour_map_ce(wks,v,res) 
 
  res@gsnLeftString = "Vector Wind"
  delete(res@cnInfoLabelOn)
  plot(2) = gsn_csm_vector_map_ce(wks,u(::4,::4),v(::4,::4),res)
;************************************************
; create panel
;************************************************
  gsn_panel(wks,plot,(/3,1/),False)             ; now draw as one plot
end