;*************************************************
; NCL Graphics: panel_8.ncl
;************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl" 
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"
;************************************************
begin
;************************************************
; read in netCDF file
;************************************************
  a = addfile("uv300.nc","r")
;************************************************
; read in zonal winds
;************************************************
  u = a->U(1,:,:)                                ; read July zonal winds
;************************************************
; create plot
;************************************************
  wks = gsn_open_wks("ps" ,"panel")             ; open a ps file
  res = True                                    ; plot mods desired

  res@cnLevelSelectionMode = "ManualLevels"     ; set manual contour levels
  res@cnMinLevelValF       = -10.               ; set min contour level
  res@cnMaxLevelValF       =  35.               ; set max contour level
  res@cnLevelSpacingF      =   5.               ; set contour spacing

  res@cnInfoLabelOrthogonalPosF = -0.07         ; move contour label up

  res@gsnDraw              = False              ; Do not draw plot
  res@gsnFrame             = False              ; Do not advance frame

  plot = new(4,graphic)                         ; create graphics array
;******************************
; first plot
;******************************
  res@tmXBLabelsOn         = False              ; do not draw bottom labels
  res@tmXBOn               = False              ; no bottom tickmarks
  res@tmYRLabelsOn         = False              ; no right labels
  res@tmYROn               = False              ; no right tickmarks
  plot(0) = gsn_csm_contour_map_ce(wks,u, res)       ; create plot object
  plot(0) = ShadeLtGtContour(plot(0),-2., 3, 31.,17)  ; shade cons<-5 and >30
;******************************
; second plot 
;******************************
  res@tmYLLabelsOn     = False
  res@tmYLOn           = False                
  plot(1) = gsn_csm_contour_map_ce(wks,u, res)  ; create plot object
  plot(1) = ShadeLtContour(plot(1), 0.2, 3)      ; shade contours < 0. 
;******************************
; three plot 
;******************************
  delete(res@tmYLLabelsOn)
  delete(res@tmYLOn) 
  delete(res@tmXBLabelsOn)
  delete(res@tmXBOn)
  plot(2) = gsn_csm_contour_map_ce(wks,u, res)  ; create plot object
  plot(2) = ShadeGtContour(plot(2),32.,17)      ; shade contours > 30.
;******************************
; fourth plot 
;******************************
  res@tmYLLabelsOn     = False
  res@tmYLOn           = False                
  plot(3) = gsn_csm_contour_map_ce(wks,u, res)  ; create plot object
  plot(3) = ShadeLtContour(plot(3), 0.2, 3)      ; shade contours < 0. 
;*******************************************
; draw panel plot with title
;*******************************************
  gsn_panel(wks,plot,(/2,2/),False)        ; create panel plot

end