;================================================;
;  Popscal_2.ncl
;================================================;
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"
; ================================================;
begin
  f         = addfile("TEMP.nc","r")

  t         = f->TEMP

  lat2d     = f->TLAT
  lon2d     = f->TLONG
  t@lon2d   = lon2d
  t@lat2d   = lat2d
;=================================================;
; Create plot
;=================================================;
  wks  = gsn_open_wks("ps","popscal")           ; open a ps file

  res                     = True                ; plot mods desired
  res@gsnDraw             = False               ; do not draw
  res@gsnFrame            = False               ; do not advance the frame
  res@cnLineLabelsOn      = False               ; turn off line labels
  res@tiMainString        = "Shade values < 5"  ; add title

  plot = gsn_csm_contour_map_ce(wks,t(0,0,:,:),res)  
;=================================================
; Shade areas less than the 5. contour level. Starting with the 
; first contour less than the given value, ShadeLtContour
; will shade all areas less then that first contour.
;=================================================  
  plot = ShadeLtContour(plot, 5.5, 17)          ; shade areas < 5.
  draw (plot)                                    ; draw the plot
  frame(wks)                                     ; advance the frame


      
  end