;*************************************************
; NCL Graphics: sat_1.ncl
;************************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
;************************************************
begin
;************************************************
; read in netCDF file
;************************************************
  cdf_file = addfile("slp.1963.nc","r") 
;************************************************
; read in data 
;************************************************
  slp=cdf_file->slp(:,::-1,:)              
  newslp = ((slp*slp@scale_factor)+slp@add_offset)*.01  
;************************************************
; plotting parameters
;************************************************
  wks = gsn_open_wks("ps","sat")

  res                            = True       ; plot mods desired

  res@cnHighLabelsOn             = True       ; turn on H labels
  res@cnHighLabelFontHeightF     = 0.024      ; change H font
  res@cnHighLabelBackgroundColor = -1         ; make H background transparent

  res@cnLowLabelsOn              = True       ; turn on L labels
  res@cnLowLabelFontHeightF      = 0.024      ; change L font
  res@cnLowLabelBackgroundColor  = -1         ; make L background transparent

  res@cnLabelDrawOrder           = "PostDraw" ; draw lables over lines

  res@mpProjection               = "Satellite" ; choose map projection
  res@mpCenterLonF               = 270.0       ; choose center lon
  res@mpCenterLatF               = 45.         ; choose center lat
  res@mpSatelliteDistF           = 3.0         ; choose satellite view

  res@mpFillOn                   = True        ; color contentinents
  res@mpFillColors               = (/0,9,28,9/); colors to draw
  res@mpOutlineOn                = True        ; turn on continental outlines
  res@mpOutlineBoundarySets      = "National"  ; add country boundaries
  res@mpGridLineDashPattern      = 2           ; make lat/lon lines dash
	
	
  res@vpXF                       = 0.1         ; size of plot
  res@vpYF                       = 0.9
  res@vpWidthF                   = 0.8
  res@vpHeightF                  = 0.7
	
  res@cnLevelSelectionMode 	= "ManualLevels"  ; manually set cont levels
  res@cnMinLevelValF       	= 948             ; min lev
  res@cnMaxLevelValF	        = 1064            ; max lev
  res@cnLevelSpacingF           = 4               ; spacing
  res@cnLineThicknessF          = 1.10            ; change line thickness

  res@tiMainString    = "~F22~SLP 1963, January 24th" ; add title
  res@sfXCStartV      = min(slp&lon)                  ; where to start x
  res@sfXCEndV        = max(slp&lon)                  ; where to end x etc
  res@sfYCStartV      = min(slp&lat)
  res@sfYCEndV        = max(slp&lat)

  map = gsn_contour_map(wks,newslp(24,:,:),res)
end