Hi Ben,
Here is a section of my code that draws a color fill plot, and then
overlays contours of statistical significance.
;==================================================================
wks = gsn_open_wks("ps","test")
gsn_define_colormap(wks,"BlWhRe")
sres = True
sres@mpGridAndLimbOn = False
sres@mpFillOn = False
sres@mpCenterLonF = 180.
sres@mpLabelsOn = False
sres@mpPerimOn = True
sres@cnLineLabelsOn = False
sres@cnInfoLabelOn = False
sres@cnFillOn = True
sres@cnMonoFillColor = False
sres@cnLinesOn = False
sres@lbLabelBarOn = True
sres@tiMainOn = False
sres@tmYLLabelFontHeightF = 0.015
sres@tmXBLabelFontHeightF = 0.015
sres@cnFillColors = (/3,20,33,37,41,45,48,-1,-1,56,59,63,68,75,88,99/)
sres@cnLevelSelectionMode = "ExplicitLevels"
sres@cnLevels = \
(/-3.,-2.5,-2.,-1.5,-1.,-.5,-0.25,0,0.25,.5,1.,1.5,2.,2.5,3./)
res = True ;resource list for T-test contours
res@cnLineColor = "black"
res@cnLineThicknessF = 1.5
res@cnLineDashPattern = 2
res@cnLevelSelectionMode = "ExplicitLevels"
res@cnLevels = (/99.,100.5/)
res@cnInfoLabelOn = False
res@tiMainOn = False
sres@gsnCenterString = "T-test overlay example"
map = gsn_csm_contour_map_overlay(wks,arr,arr_ttest,sres,res)
;==============================================================================
arr contains the temperature difference, arr_ttest contains the ttest
values. All areas with t-test values > 99% are contoured with a thick
black line.
Hope this helps, good luck.
Adam
Benjamin Lamptey wrote:
> Hello,
> I should be grateful if someone could direct me to an example of a color plot (difference
> in temperature) with statistical significance imposed on it.
>
> I can make black and white plots with the statistically significant areas
> either shaded with a color or stippled but that is not what I want.
>
> I have seen the following plots
> http://www.ncl.ucar.edu/Applications/Scripts/conOncon_4.ncl
> http://www.ncl.ucar.edu/Applications/Scripts/conOncon_8.ncl
>
> but like I said that is not what I want.
> Thanks
> Ben
-- -------------------------------------------------------------- Adam Phillips asphilli@ucar.edu National Center for Atmospheric Research tel: (303) 497-1726 ESSL/CGD fax: (303) 497-1333 P.O. Box 3000 Boulder, CO 80307-3000 http://www.cgd.ucar.edu/cas/asphilli _______________________________________________ ncl-talk mailing list ncl-talk@ucar.edu http://mailman.ucar.edu/mailman/listinfo/ncl-talk
This archive was generated by hypermail 2b29 : Mon Apr 25 2005 - 15:52:09 MDT