Re: Difference from zonal average

In the line

  plot = gsn_csm_pres_hgt(wks, tavg(nt,:,:)-t(nt,:,:,40), res ) ;
(lev,lat)

The "tavg(nt,:,:)-t(nt,:,:,40)" has no meta data associated with it.

It should be replaced with

  dif = tavg(nt,:,:)-t(nt,:,:,40)
  copy_VarMeta(tavg(nt,:,:), dif)
  dif_at_long_name = "Tzonal-T(lon="+lon(40)+")"
  plot = gsn_csm_pres_hgt(wks, dif , res ) ; (lev,lat)

Helen Parish wrote:
> I am trying to plot the difference between the zonal average
> temperature, and the temperature at a given longitude. Once a
> particular longitude is chosen, these fields should have the same
> dimensions. I get the following error when I try to do this:
>
> (0) gsn_csm_pres_hgt: Fatal: The first dimension of the input data
> must
> (0) have a coordinate variable called 'lev.'
> (0) Cannot create plot.
> fatal:Illegal right-hand side type for assignment
> fatal:Execute: Error occurred at or near line 80 in file tempdiff.ncl
>
>
>
> The following is the code I am trying to use:
>
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
> begin
> ; input file
> diri = "./"
> fili = "profile45large2a.cam2.h0.0035-11-06-00000.nc"
> fi = addfile (diri+fili, "r")
> ; output file
> diro = "./"
> filo = "helen.nc"
> system ("/bin/rm -f "+diro+filo) ; remove any pre-exist file
> fo = addfile (diro+filo, "c")
> ; add any file attributes
> fo_at_title = fi_at_title + ": Selected Variables at pressure levels"
> fo_at_history = systemfunc ("date")
> fo_at_source = fi_at_source
> fo_at_case = fi_at_case
> fo_at_Conventions = fi_at_Conventions
>
> Var = (/ "T" , "Q", "U", "V"/) ; select variable to be
> interpolated.
> nVar = dimsizes (Var)
> ; desired output levels
> lev_p = (/ 91500., 90000., 87500., 80000., 67500., 50000., 30000.,
> 20000., 10000., 5000., 3000., 1500., 750., 390., 200., 100., 50.,25.,
> 14., 7., 3.5, 1.9, 0.95, 0.4, 0.1, 0.03 /)
> lev_p!0 = "lev_p" ; variable and dimension name
> the same
> lev_p&lev_p = lev_p ; create coordinate variable
> lev_p_at_long_name = "pressure" ; attach some attributes
> lev_p_at_units = "hPa"
> lev_p_at_positive = "down"
>
> hyam = fi->hyam ; read hybrid info
> hybm = fi->hybm
> PS = fi->PS
> P0mb = 0.01*fi->P0
>
> do n=0,nVar-1 ; loop over the variables
> X = fi->$Var(n)$
> Xp = vinth2p (X, hyam, hybm, lev_p ,PS, 1, P0mb, 2, True)
> copy_VarAtts(X, Xp)
> fo->$Var(n)$ = Xp ; write to netCDF file
> print (Var(n)+": interpolated and written to netCDF")
> end do
>
> end
> ;***********************
> ; merid.ncl
> ;***********************
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
> ;***********************
> begin
> f = addfile ("helen.nc","r")
> print(f)
> t = f->T
> printVarSummary( t )
>
> dimu = dimsizes( t )
> ntim = dimu(0)
> klvl = dimu(1)
> nlon = dimu(2)
> mlon = dimu(3)
>
> tavg = dim_avg_Wrap(t)
> ;***********************
> ; Create Plot
> ;***********************
> wks = gsn_open_wks ("pdf", "profile45large2a351106tempdiff"
> ) ; open workstation
> gsn_define_colormap(wks,"rainbow") ; choose colormap
>
> res = True
> res_at_cnFillOn = True
> res_at_lbLabelAutoStride = True
> res_at_gsnMaximize = True ; if [ps, eps, pdf] make large
> res_at_gsnSpreadColors = True ; span color map
>
> do nt=0,ntim-1
>
> res_at_gsnCenterString = "profile45large2a351106tempdiff"
> ; plot = gsn_csm_pres_hgt(wks, t(nt,:,:,0), res ) ; (lev,lat)
> ; plot = gsn_csm_pres_hgt(wks, tavg(nt,:,:), res ) ; (lev,lat)
> plot = gsn_csm_pres_hgt(wks, tavg(nt,:,:)-t(nt,:,:,40), res )
> ; (lev,lat)
>
> res_at_trYReverse = True
> ; plot = gsn_csm_contour (wks, t(nt,:,:,0), res ) ; (lev,lat)
> ; plot = gsn_csm_contour (wks, t(nt,:,0,:), res ) ; (lev,lon)
>
> kl = 5
> res_at_mpFillOn = False
> res_at_mpGridAndLimbOn = True
> res_at_mpGridLineDashPattern = 2
> res_at_mpOutlineBoundarySets = "NoBoundaries"
> res_at_mpCenterLonF = 180.
> res_at_gsnCenterString = res_at_gsnCenterString+" p="+t&lev_p(kl)
> ; plot = gsn_csm_contour_map_ce (wks, t(nt,kl,:,:), res )
>
> end do
>
> end
>
>
>
> Thanks,
> Helen.
> _______________________________________________
> ncl-talk mailing list
> ncl-talk_at_ucar.edu
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk

-- 
======================================================
Dennis J. Shea                  tel: 303-497-1361    |
P.O. Box 3000                   fax: 303-497-1333    |
Climate Analysis Section                             |
Climate & Global Dynamics Div.                       |
National Center for Atmospheric Research             |
Boulder, CO  80307                                   |
USA                        email: shea 'at' ucar.edu |
======================================================
_______________________________________________
ncl-talk mailing list
ncl-talk_at_ucar.edu
http://mailman.ucar.edu/mailman/listinfo/ncl-talk