Re: confidence intervals

Hi Debashish,

By using the below code you can overlay the contours over the correlation
shaded plot which is significant at 90,95 99 confidence level....I think it
will be useful to you....
Good luck...

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
begin
;**************************************************************

in1=addfile("input1.nc","r")
x=in1->x
;***************************************************************
in2=addfile("input2","r")
y=in2->y
;********************************************************
cor=escorc(x,y)
;*****************************************************
Nx=59
prob=100*(1-rtest(cor,Nx,0))
copy_VarCoords(cor,prob)
;*****************************************************
wks=gsn_open_wks("eps","cor_signi_test")
gsn_define_colormap(wks,"gui_default")
res=True
res@gsnFrame=False
res@gsnDraw=False
res@cnFillOn=True
res@gsnSpreadColors=True
res@cnLinesOn=False
res@lbLabelAutoStride=True
res@cnInfoLabelOn=False
res@cnLevelSelectionMode="ManualLevels"
res@cnMinLevelValF=-0.7
res@cnMaxLevelValF=0.7
res@cnLevelSpacingF=0.1
;***************************************************************
  res2 = True
  res2@gsnFrame=False
  res2@gsnDraw=False
  res2@cnLevelSelectionMode = "ExplicitLevels"
  res2@cnLevels=(/90,95,99/)
  res2@cnLineLabelsOn = True
;*********************************************************
plot = gsn_csm_contour_map_overlay(wks,cor,prob,res,res2)
draw(plot)
frame(wks)
end

-- 
**********************************
Sabeerali
Climate and Global Modeling Division
Indian Institute of Tropical Meteorology
Pashan, Pune, 411 008
****************************************

_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Tue Mar 30 23:05:48 2010