Re: Laber bar unwanted grey color box

Hi Ugo,

It looks like your colormap has gray at the end. You can tell gsn_csm_contour to not span the full color map by setting:

   res1@gsnSpreadColorEnd = -2 ; Default is -1 (last color)

The -2 says to stop at the second-to-last-color in the color map when spanning it for the contour colors.

--Mary

On Aug 30, 2011, at 12:59 PM, ugo merlini wrote:

> Hi,
>
> in the attached plot the laber bar draw a grey box at the end and I'm not able to eliminate.
>
> http://i103.photobucket.com/albums/m136/ugo73/temp-1.png
>
> How can i delete it?
>
> regards
>
> Ugo
>
> here the script
>
> ;----------------------------------------------------------------------
> ; This example shows how to read geographic data
> ; from Natural Earth shapefiles
> ; and plot them as polylines and polygons.
> ;----------------------------------------------------------------------
> ; This particular example plots data for Switzerland.
> ;----------------------------------------------------------------------
> ; Download the shapefiles from http://www.naturalearthdata.com/
> ; Unzip to a directory
> ;----------------------------------------------------------------------
>
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"
>
> begin
>
> ;*****************************************
> ; Open workstation and define colormap *
> ;*****************************************
>
> wks_type = "png" ; use "newpdf" instead of "pdf" for smaller files
> wks_type@wkWidth = 1024
> wks_type@wkHeight = 1024
> wks = gsn_open_wks(wks_type,"temp")
> gsn_define_colormap(wks,"tbr_var_0-500") ; choose colormap
>
> ;*****************
> ; Generare map *
> ;*****************
> ;--- resouces for map
> res = True ; plot mods desired
> res@mpProjection = "LambertConformal" ; choose projection
>
> res = True ; plot mods desired
>
> res@gsnMaximize = True
> res@gsnDraw = False ; do not draw the plot
> res@gsnFrame = False ; do not flip the page
>
> res@mpProjection = "LambertConformal" ; choose projection
> res@mpLimitMode = "LatLon"
> res@mpMaxLonF = 47.0
> res@mpMaxLatF = 88.5
> res@mpMinLatF = 27.0
> res@mpMinLonF = -43.0
> res@mpGridAndLimbOn = True ; turn on grid lines
> res@mpGridLineDashPattern = 10 ; lat/lon lines dashed
>
>
> drawNDCGrid(wks)
>
> map = gsn_csm_map(wks,res)
>
> ;--- create map from shapefiles
>
> fnames = "/mnt/internetserver/map/shapefile/europa/aaa_full/" + (/"europa"/) + ".shp" ; Files to be open
> linecolors = (/"Black"/) ; color definition for each shapefile
> fillcolors = (/"Transparent"/) ; Fill color definition for each shapefile
> thicks = (/2/) ; Thickness for each shapefile
> lnres = True ; resources for polylines
> plres = True
> prims = True
> lines = True
> do n=0,dimsizes(fnames)-1 ; Loop through files that we want to read geographic information from.
> f = addfile(fnames(n),"r") ; Open the shapefile number n.
> segments = f->segments ; Read data off the shapefile
> geometry = f->geometry
> segsDims = dimsizes(segments)
> geomDims = dimsizes(geometry)
> geom_segIndex = f@geom_segIndex ; Read global attributes
> geom_numSegs = f@geom_numSegs
> segs_xyzIndex = f@segs_xyzIndex
> segs_numPnts = f@segs_numPnts
> geometry_type = f@geometry_type
> numFeatures = geomDims(0)
> lon = f->x
> lat = f->y
> if (geometry_type.eq."polygon") then ; Put if statement outside the loop
> plres@gsFillColor = fillcolors(n)
> plres@gsEdgesOn = True ; Draw border around polygons
> plres@gsEdgeColor = linecolors(n)
> plres@gsEdgeThicknessF = thicks(n)
> do i=0, numFeatures-1 ; Section to draw polygons on map.
> startSegment = geometry(i, geom_segIndex)
> numSegments = geometry(i, geom_numSegs)
> do seg=startSegment, startSegment+numSegments-1
> startPT = segments(seg, segs_xyzIndex)
> endPT = startPT + segments(seg, segs_numPnts) - 1
> dumstr = unique_string("lines") ; This call adds the polygon.
> map@$dumstr$ = gsn_add_polygon(wks, map , lon(startPT:endPT), lat(startPT:endPT), plres)
> end do
> end do
> else
> lnres@gsLineThicknessF = thicks(n)
> lnres@gsLineColor = linecolors(n)
> do i=0, numFeatures-1 ; Section to draw polylines on map.
> startSegment = geometry(i, geom_segIndex)
> numSegments = geometry(i, geom_numSegs)
> do seg=startSegment, startSegment+numSegments-1
> startPT = segments(seg, segs_xyzIndex)
> endPT = startPT + segments(seg, segs_numPnts) - 1
> dumstr = unique_string("primitive") ; This call adds the line segment.
> map@$dumstr$ = gsn_add_polyline(wks, map, lon(startPT:endPT), lat(startPT:endPT), lnres)
> end do
> end do
> end if
> delete(lat) ; Clean up before we read in same variables again.
> delete(lon)
> delete(segments)
> delete(geometry)
> delete(segsDims)
> delete(geomDims)
> end do
>
> ;******************
> ; read gfs data *
> ;******************
>
> url = "http://nomad1.ncep.noaa.gov:9090/dods/gfs_master/gfs20110830/"
> ;systemdate = systemfunc("date +%H")
>
> ;if ((systemdate.ge.06).and.(systemdate.lt.12)) then
> filename = url + "gfs_master_00z"
> ;end if
> ;if ((systemdate.ge.12).and.(systemdate.lt.18)) then
> ; filename = url + "gfs_master_06z"
> ;end if
> ;if ((systemdate.ge.18).and.(systemdate.lt.23)) then
> ; filename = url + "gfs_master_06z"
> ;end if
> ;if ((systemdate.ge.23).and.(systemdate.lt.06)) then
> ; filename = url + "gfs_master_18z"
> ;end if
>
> exists = isfilepresent(filename)
> if(.not.exists) then
> print("OPeNDAP isfilepresent test unsuccessful.")
> print("Either file doesn't exist, or NCL does not have OPeNDAP capabilities on this system")
> else
> print("OPeNDAP isfilepresent test successful.")
> gfs = addfile(filename,"r")
> vars = getfilevarnames(gfs)
> end if
>
> ;*******************************
> ; 2 metres temperature plot *
> ;*******************************
> ;--- resouces for 2 metres temperature plot
> res1= True
>
> res1@gsnMaximize = True
> res1@gsnDraw = False ; do not draw the plot
> res1@gsnFrame = False ; do not flip the page
> res1@gsnAddCyclic = True
> res1@gsnSpreadColors = True ; use entire color map
> res1@gsnContourNegLineDashPattern = 1
>
> res1@cnFillOn = True ; turn on color
> res1@cnLinesOn = True ; turn contour lines
> res1@cnLineLabelsOn = True
> res1@cnLineDashSegLenF = 0.04
> res1@cnLineLabelBackgroundColor = "Transparent" ; Transparent bckgrnd around label
> res1@cnLineLabelFont = "times-roman"
> res1@cnLineLabelFontHeightF = 0.006
> res1@cnLineLabelPlacementMode = "Constant"
>
> res1@cnLevelSelectionMode = "ManualLevels"
> res1@cnMinLevelValF = -51
> res1@cnMaxLevelValF = 51
> res1@cnLevelSpacingF = 1
> res1@cnLevelFlags = (/"NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine","NoLine","NoLine","NoLine","LineAndLabel","NoLine","NoLine","NoLine","NoLine", \
> "LineAndLabel","NoLine"/)
>
> res1@lbLabelsOn = True ; turn on the labels
> res1@lbLabelAutoStride = True ; let NCL determine label spacing
> res1@lbLeftMarginF = 0.001
> res1@lbOrientation = "horizontal"
> res1@lbBoxLinesOn = True ; turn on lines between labelbar colors
> res1@lbLabelFont= "times-roman" ; font
> res1@lbLabelFontHeightF= 0.007 ; set the label size
> res1@lbLabelAlignment = "BoxCenters" ; label orientation
>
>
>
>
>
> res1@pmLabelBarHeightF = 0.05
>
>
> ;---data for 2 metres temperature plot
>
> TEMP2M = gfs->tmp2m(:,:,:) ; temperature
> NTIMES = dimsizes(gfs->time) ; number of times in the file
> TEMP2M = TEMP2M - 273.15
> TEMP2M@units = "(C)"
> TEMP2M@long_name = "Temperatura a 2 metri dal suolo"
> do it = 0,0
> plot = gsn_csm_contour(wks,TEMP2M(it,:,:),res1)
> overlay(map,plot)
> draw(map)
> frame(wks)
> end do
> do it = 0,0
> if (it.le.8) then
> system("mv temp.00000" + (it+1) + ".png" + " temperatura0" + (it) + "_" + systemfunc("date +%Y%m%d%H") + ".png")
> end if
> if (it.eq.9) then
> system("mv temp.0000" + (it+1) + ".png" + " temperatura0" + (it) + "_" + systemfunc("date +%Y%m%d%H") + ".png")
> end if
> if (it.ge.10) then
> system("mv temp.0000" + (it+1) + ".png" + " temperatura" + (it) + "_" + systemfunc("date +%Y%m%d%H") + ".png")
> end if
> end do
> end
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk

_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Tue Aug 30 13:28:51 2011