Re: wind

It is not possible to have an example script for all types of plots.
A simple very basic plot of what you want is appended.

You can read and experiment with the following:
    http://www.ncl.ucar.edu/Applications/tickmarks.shtml
    http://www.ncl.ucar.edu/Applications/time_labels.shtml
========================================================
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

   N = 100
   u = abs( random_normal(0,5,N) )
   v = random_normal(0,2,N)
   s = sqrt(u^2 + v^2)
   xx = fspan(1,N,N)

   ywnd = max(s)*0.85 ; arbitrary location for
                                         ; wind barbs

   wks = gsn_open_wks ("x11","xy_wind")
   res = True ; plot mods desired
   res@gsnFrame = False ; don't advance frame yet

   res@vpHeightF= 0.4 ; change aspect ratio of plot
   res@vpWidthF = 0.8

  ;res@trYMinF = 0.0 ; min value on y-axis
  ;res@trYMaxF = 20.0 ; max value on y-axis

   res@vpXF = 0.1 ; start plot at x ndc coord

   res@tiYAxisString = "" ; y-axis label
   res@tiMainString = "TEST" ; title

   plot = gsn_csm_xy (wks,xx,s,res) ; create base plot

   wmsetp("wdf", 1) ; meteorological wind direction

   do n=0,N-1,5 ; arbitrary spacing
      wmbarb(wks,xx(n), ywnd, u(n), v(n))
   end do
   frame(wks) ; now advance frame

On 1/31/12 1:40 AM, nlcheng wrote:
> how can I draw the picture below ? it is the time series of wind
> the horizontal axis is time and the vertical axis is the speed of wind .
> I can not find any script at the ncl website.
> could you help me ,thank you very much!
>
>
>
>
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk
_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Tue Jan 31 15:52:23 2012