load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
  tf = addfile("meccatemp.cdf","r")
  T  = tf->t(0,:,:)                      ; T will have metadata attached.

  wks = gsn_open_wks("ps","contour2d")   ; Open PS file called "contour2d.ps"

  gsn_define_colormap(wks,"rainbow+white+gray")  ; Change color map

  res                      = True            ; Set some plot options

  res@cnLevelSelectionMode = "ManualLevels"  ; Set contour levels manually
  res@cnMinLevelValF       = 195             ; Minimum contour level
  res@cnMaxLevelValF       = 328             ; Maximum contour level
  res@cnLevelSpacingF      = 2.25            ; Contour level spacing

  res@cnFillOn             = True            ; Turn on contour fill
  res@cnLinesOn            = False           ; Turn off contour lines

  res@gsnSpreadColors      = True            ; Span full color map
  res@gsnSpreadColorStart  = 14              ; Start at color index 14
  res@gsnSpreadColorEnd    = -3              ; Stop at 3rd color from end

  res@lbBoxLinesOn         = False           ; Turn off labelbar box lines
  res@lbLabelAutoStride    = True            ; Control labelbar labels.

  plot = gsn_csm_contour_map(wks,T,res)      ; Call the gsn_csm function for
                                             ; drawing contours over a map.
end