load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
  f     = addfile ("ruc2.bgrb.20020418.i12.f00.grb","r")
  vpt   = f->VPTMP_252_HYBL(0,:,:)
  lat2d = f->gridlat_252              ; 2D latitude grid
  lon2d = f->gridlon_252              ; 2D longitude grid

  vpt@lat2d = lat2d                   ; Must attach lat2d and
  vpt@lon2d = lon2d                   ; lon2d as special attributes.

  wks = gsn_open_wks("ps","contour6c")    ; Open "contour6c.ps" PS file.
  gsn_define_colormap(wks,"gui_default")  ; Change color map.

  res                   = True            ; Plot options desired.
  res@cnFillOn          = True            ; Turn on contour fill
  res@cnLinesOn         = False           ; Contour lines off
  res@gsnSpreadColors   = True            ; Span full color map

  res@mpLimitMode       = "Corners"         ; Choose range of map.
  res@mpLeftCornerLatF  = lat2d@corners(0)
  res@mpLeftCornerLonF  = lon2d@corners(0)
  res@mpRightCornerLatF = lat2d@corners(2)
  res@mpRightCornerLonF = lon2d@corners(2)

  plot = gsn_csm_contour_map(wks,vpt,res)    ; Call gsn_csm function for
                                             ; drawings contours over a map.
end