load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
  print("Warning: this example can be slow!")

  f = addfile("fh.0000_tl.press_gr.egrdsf.partial.nc","r")
  veg       = f->VGTYP_96_SFC
  veg@lat2d = f->gridlat_96
  veg@lon2d = f->gridlon_96

  wks = gsn_open_wks("ps","contour7e")    ; Open X11 window.
  gsn_define_colormap(wks,"BlAqGrYeOrRe")  ; Change color map.

  res                        = True                ; Plot options desired.
  res@gsnMaximize            = True                ; Maximize plot in frame.
  res@cnFillOn               = True                ; Contour fill on
  res@cnLinesOn              = False               ; Turn off contour lines
  res@gsnSpreadColors        = True                ; Span full color map
  res@gsnSpreadColorStart    =  16                 ; Start color in color map
  res@gsnSpreadColorEnd      = 190                 ; End color in color map
  res@cnFillMode             = "RasterFill"        ; Must use raster fill,
                                                   ; or will run out of memory.

  res@cnLevelSelectionMode   = "ExplicitLevels"    ; Set contour levels
  res@cnLevels               = ispan(0,14,1)       ; explicitly.

  res@mpProjection           = "LambertConformal"
  res@mpLambertMeridianF     = -95                ; Central meridian
  res@mpLambertParallel1F    =  33                ; Two parallels
  res@mpLambertParallel2F    =  5

  res@mpLimitMode            = "LatLon"
  res@mpMinLatF              =   24                ; Zoom in on
  res@mpMaxLatF              =   50                ; a smaller
  res@mpMinLonF              = -125                ; latitude and
  res@mpMaxLonF              =  -65                ; longitude area.

  map = gsn_csm_contour_map(wks,veg,res)   ; Call the gsn_csm function for
                                           ; drawing contours over a map.
end