load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"   
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"  

begin
  a = addfile("sst8292a.nc","r")
  b = addfile("olr7991a.nc","r")
;
; Read in sea surface temperature anomalies.
; Read in olr anomalies.
; Determine the indexes corresponding to Dec 1982.
;
  sst      = a->SSTA
  olr      = b->OLRA
  date_sst = a->date
  date_olr = b->date
  ind_sst  = ind(date_sst.eq.198212)
  ind_olr  = ind(date_olr.eq.198212)

  wks = gsn_open_wks("ps","contour9e")        ; Open "contour9e.ps"

  gsn_define_colormap(wks,"GreenYellow")      ; Change color map

  res1                      = True          ; Res list for 1st data array

  res1@cnLevelSelectionMode = "ManualLevels"     ; Set manual contour levels
  res1@cnMinLevelValF       = -5.                ; Set min contour level
  res1@cnMaxLevelValF       =  5.                ; Set max contour level
  res1@cnLevelSpacingF      =  0.5               ; Set contour spacing

  res1@cnFillDrawOrder  = "Predraw"     ; Draw line contours before filled map

  res1@mpCenterLonF         = 180                ; Center plot at 180
  res1@mpMinLonF            = 100                ; Select a subregion
  res1@mpMaxLonF            = 260
  res1@mpMinLatF            = -60 
  res1@mpMaxLatF            =  60

; Set some resources controlling the subtitles at the top.

  res1@gsnCenterString               = "December 1982"
  res1@gsnLeftString                 = "degC" 
  res1@gsnRightString                = "(W m s~S~-2~N~)"   ; function code use
  res1@gsnStringFontHeightF          = 0.015
  res1@gsnLeftStringOrthogonalPosF   = 0.01
  res1@gsnCenterStringOrthogonalPosF = 0.017
  res1@gsnRightStringOrthogonalPosF  = 0.01

  res1@tmXTOn                        = False     ; Turn off top tick marks.

  res2                               = True      ; Res list for 2nd data array

  res2@cnInfoLabelOrthogonalPosF    = -0.42      ; Move info label up

  res2@cnLevelSelectionMode = "ManualLevels"     ; Set manual contour levels
  res2@cnMinLevelValF       = -70                ; Set min contour level
  res2@cnMaxLevelValF       =  30                ; Set max contour level
  res2@cnLevelSpacingF      =  10                ; Set contour spacing

  plot = gsn_csm_contour_map_overlay(wks,sst(ind_sst,:,:),\
                                     olr(ind_olr,:,:),res1,res2)
end