load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
  npts = 100
  lat  = random_uniform( 25, 50,(/2,npts/))  ; Create some dummy lat/lon data
  lon  = random_uniform(235,290,(/2,npts/))  ; containing the position of
                                             ; the 2 sets of markers.

  wks = gsn_open_wks("ps","poly2d")     ; Open "poly2d.ps" file
  gsn_define_colormap(wks,(/"white","black","PaleGreen","LightBlue", \
                            "brown","blue"/))

  mpres              = True             ; Map resources desired.
  mpres@gsnFrame     = False            ; Don't advance the frame

  mpres@mpMinLatF    = 25               ; Zoom in on United States.
  mpres@mpMaxLatF    = 50
  mpres@mpMinLonF    = 235
  mpres@mpMaxLonF    = 290

;                           default       ocean      land    inland water
  mpres@mpFillColors = (/"background","LightBlue","PaleGreen","LightBlue"/)

  map = gsn_csm_map(wks,mpres)          ; Call gsn_csm_map to draw a map.

;
; Create logical variables to hold the marker and text resources.
;
  mkres = True
  txres = True
  txres@txFontHeightF = 0.03           ; Text font height
  txres@txJust        = "CenterLeft"   ; Text justification point

  mkres@gsMarkerSizeF = .01         ; Default is 0.007
  mkres@gsMarkerIndex = 16          ; Use filled dots for 1st set of markers.
  mkres@gsMarkerColor = "Brown"     ; Color for 1st set of markers
  gsn_polymarker(wks,map,lon(0,:),lat(0,:),mkres)

  mkres@gsMarkerIndex = 13          ; Use stars for 2nd set of markers.
  mkres@gsMarkerColor = "Blue"      ; Color for 2nd set of markers
  gsn_polymarker(wks,map,lon(1,:),lat(1,:),mkres)

  frame(wks)
end