load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
  f       = addfile("pop.nc","r")      ; POP model data.
  u       = f->urot
  v       = f->vrot
  u@lat2d = f->lat2d
  u@lon2d = f->lon2d
  v@lat2d = f->lat2d
  v@lon2d = f->lon2d

  wks = gsn_open_wks("ps","vector1f")      ; Open PS file called "vector1f.ps"
  gsn_define_colormap(wks,"gui_default")   ; Change color map.

  res                      = True          ; Plot options set
  res@gsnAddCyclic         = True          ; Add a longitude cyclic point.
  res@vcMonoLineArrowColor = False         ; Turn on color vectors
  res@vcRefMagnitudeF      = 40            ; Define reference magnitude
  res@vcRefLengthF         = 0.045         ; Define length of vector reference

  res@vcRefAnnoOrthogonalPosF   = -0.13    ; Move reference into plot.
  res@vcRefAnnoArrowUseVecColor = False    ; Allow us to change ref vec color
  res@vcRefAnnoArrowLineColor   = "black"  ; Black ref vector
;
; Instead of thinning the vectors by subscripting the data with "::4",
; you can instead thin the vectors with the resource below.
;
  res@vcMinDistanceF       = 0.005         ; Thin the vectors

  res@mpFillDrawOrder      = "Postdraw"    ; Draw filled map last

  plot = gsn_csm_vector_map(wks,u,v,res)   ; Call the gsn_csm function for
                                           ; drawing the vectors over a map.
end