Heiko,
With a little work using existing characters you can use
function codes in your text string specification to get
umlauts. Included below is a sample.
Fred Clare
---------------------------------------------
Fred Clare fred AT ucar.edu 303-497-1284
Visualization & Enabling Technologies Section
NCAR Scientific Computing Division
---------------------------------------------
begin
;
; Default output is to an X workstation.
;
NCGM=0
X11=1
PS=0
if (NCGM .eq. 1) then
;
; Create an ncgmWorkstation object.
;
workstation_id = create "txWork" ncgmWorkstationClass defaultapp
"wkMetaName" : "tx04n.ncgm"
end create
else
if (X11 .eq. 1) then
;
; Create an XWorkstation object.
;
workstation_id = create "txWork" xWorkstationClass defaultapp
"wkPause" : True
end create
else
if (PS .eq. 1) then
;
; Create a PSWorkstation object.
;
workstation_id = create "txWork" psWorkstationClass defaultapp
"wkPSFileName" : "tx04n.ps"
end create
end if
end if
end if
text_item_id = create "umlauts" textItemClass workstation_id
"txJust" : 4
"txFont" : 25
"txFontHeightF" : .1
;
; Explanation of the text string function codes:
;
; :F22: - Select font 22 (Helvetica bold)
; :H-15F35: - Move 15 digitized font units left and select font 35.
; The character "H" in font 35 is an umlaut.
; :H4F22: - Move 4 digitized font units right and select font 22.
; :H-14F35: - Move 14 digitized font units left and select font 35.
; :H3F22: - Move 3 digitized font units right and select font 22.
;
"txString" : ":F22:u:H-15F35:H:H4F22:berho:H-14F35:H:H3F22:hen"
"txPosXF" : .5
"txPosYF" : .7
end create
draw(text_item_id)
setvalues text_item_id
"txFontHeightF" : .1
"txPosXF" : .5
"txPosYF" : .3
;
; Explanation of the text string function codes:
;
; :F22: - Select font 22.
; :H-16V6F35: - Move 16 digitized units left, 6 digitized units
; up, and select font 35.
; :V-6H5F22: - Move 6 digitized units down and select font 22.
; :H-13F35: - Move 13 digitized units left and select font 35.
; :F22H2: - Select font 22 and move 2 digitized units right.
;
"txString" : ":F22:U:H-16V6F35:H:V-6H5F22:bersta:H-13F35:H:F22H2:nder"
end setvalues
draw(text_item_id)
frame(workstation_id)
end
_______________________________________________
ncl-talk mailing list
ncl-talk AT ucar.edu
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
This archive was generated by hypermail 2b29 : Mon Jun 16 2003 - 16:49:17 MDT