Re: run the codes without any results after 1 hours.

Hello

Another person looked at this. Note: it is your responsibility
to examine the output from printVarSummary. This is untested.

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
begin
;**************************************************************
   in1 = addfile("olr.raw.nc","r")
   x = in1->olr
    printVarSummary(x)
;***************************************************************
   in2 = addfile("mjo_waves.nc","r")
   y = in2->mjo
    printVarSummary(y)
;********************************************************
  ;mxlag = 0
  ;ccr = esccr(x(lat|:,lon|:,time|:), y(lat|:,lon|:,time|:), mxlag)
;***

   ccr = escorc(x(lat|:,lon|:,time|:), y(lat|:,lon|:,time|:))
   printVarSummary(ccr)
   ccr!0 = "lat"
   ccr&lat = x&lat
   ccr!1 = "lon"
   ccr&lon = x&lon
   printVarSummary(ccr)

;*****************************************************
   Nx = dimsizes(x&time)
   print(Nx)

   prob = 100*(1-rtest(ccr,Nx,0))
   copy_VarCoords(ccr,prob)
   prob@long_name = "probability"
   printVarSummary(prob)
;*****************************************************
wks=gsn_open_wks("eps","cor_signi_test")
gsn_define_colormap(wks,"gui_default")
res=True
res@gsnFrame=False
res@gsnDraw=False
res@cnFillOn=True
res@gsnSpreadColors=True
res@cnLinesOn=False
res@lbLabelAutoStride=True
res@cnInfoLabelOn=False
res@cnLevelSelectionMode="ManualLevels"
res@cnMinLevelValF=-0.7
res@cnMaxLevelValF=0.7
res@cnLevelSpacingF=0.1
;***************************************************************
   res2 = True
   res2@gsnFrame=False
   res2@gsnDraw=False
   res2@cnLevelSelectionMode = "ExplicitLevels"
   res2@cnLevels=(/90,95,99/)
   res2@cnLineLabelsOn = True
;*********************************************************

;**********************
plot = gsn_csm_contour_map_overlay(wks,ccr,prob,res,res2)
draw(plot)
frame(wks)
end

On 12/5/12 12:48 PM, antonio avio wrote:
> Hi Dennis
>
> I really need your help,
> i have a script attached, i run my code but it works without stop (after 1
> hours) and results.
> I have put the data to ftp incoming
> as X: *olr.raw.nc*
> as Y: *mjo_waves.nc*
> *
> *
> I really hope your help as an expert.
> I almost give up to figure out whats the matter in my code.
> The goal is to plot the contour correlation and significance 90%,95% and
> 99% in one figure.
>
> Thanks a lot
> Antonio
> Spain.
>
_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Thu Dec 6 21:53:01 2012