begin
a = addfile("atmos2.nc","r") ; Read in first time step
t = a->TS(0,:,:) ; of atmospheric data.
u = a->U(0,1,:,:)
v = a->V(0,1,:,:)
wks = gsn_open_wks("x11", "contour3i") ; Open png file "contour3i.png"
res = True ; Plot mods desired
res@gsnPolar = "NH" ; Specify northern hemisphere
res@mpFillOn = False ; Turn off map fill
res@mpMinLatF = 60 ; Default is 0.
cmap = read_colormap_file("wgne15")
res@cnFillPalette = cmap(0:12,:) ; Skip last two colors
res@gsnLeftString = "Wind Velocity over Surface Temperature"
res@gsnRightString = "Degrees K"
res@vcRefMagnitudeF = 20 ; Vector magnitude
res@vcRefLengthF = 0.04 ; Size of ref vector
res@vcMinDistanceF = 0.02 ; Thins arrows near pole
res@vcGlyphStyle = "CurlyVector" ; Turns on curly vectors
res@cnFillOn = True ; Turn on contour fill
res@cnLevelSpacingF = 3 ; Interval spacing
res@cnLinesOn = False ; No contour lines
res@gsnScalarContour = True ; Vectors over filled contours
;
; This is ice data which has a gap in the tropics, so we need to
; explicitly pass the range of the data to plot. Since we are coloring
; the vectors, this range should also match the MinLatF above, since the
; range for the colors is chosen over the full data passed, and not the
; map limits.
;
plot = gsn_csm_vector_scalar_map_polar(wks,u({60:90},:),v({60:90},:), \
t({60:90},:),res)
end