Re: Omega to m/s

Hi Siji,

The following is approximate:

     omega = -density*gravity*w

hence

     w = -omega/(density*gravity)

so [UNTESTED .... VERIFY UNITS]

function OMEGA_TO_W (omega, p, t)
; first order conversion: w = -omega/(density*gravity)
; omega_at_units = "Pa/sec"
; p_at_units = "Pa"
; t_at_units = "K"

local rank_omega, rank_t, rank_p, RGAS, GRAV, rho, w
begin
   rank_omega = dimsizes( dimsizes(omega) )
   rank_t = dimsizes( dimsizes( t ) )
   rank_p = dimsizes( dimsizes( p ) )

   if (rank_omega.ne.rank_t .or. rank_omega.ne.rank_p) then
       print("OMEGA_TO_W: omega, p, t must be the same rank")
       quit
   end if

   RGAS = 287. ; J/(kg-K) => m2/(s2 K)
   GRAV = 9.8 ; m/s2
   rho = p/(RGAS*t) ; density => kg/m3

   w = -omega/(rho*GRAV)

   w_at_long_name = "vertical velocity"
   w_at_units = "m/s"
   copy_VarCoords( omega, w)
   return( w )
end

Sijikumar S wrote:
> Hello,
>
> Searching for a method in NCL to convert 4D Pressure Vertical Velocity
> Omega (Pa/sec) data to Geometrical Vertical velocity (m/s).
>
> Thanks for any suggestions
>
> Siji
>
>
> ------------------------------------------------------------------------
>
> _______________________________________________
> ncl-talk mailing list
> ncl-talk_at_ucar.edu
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk

-- 
--------------------------------------------------------------
Adam Phillips			             asphilli_at_ucar.edu
National Center for Atmospheric Research   tel: (303) 497-1726
ESSL/CGD/CAS                               fax: (303) 497-1333
P.O. Box 3000				
Boulder, CO 80307-3000	  http://www.cgd.ucar.edu/cas/asphilli
_______________________________________________
ncl-talk mailing list
ncl-talk_at_ucar.edu
http://mailman.ucar.edu/mailman/listinfo/ncl-talk