Re: How to increase the plot height in panel plot...

Hi Sabeerali,

The problem is that you are trying to change the height of a map plot. This is not allowed by default in NCL, because you will be skewing your map projection.

If you really want to do this, then you also need to set res@mpShapeMode to = "FreeAspect".

I'll add an example to the viewport page on this, using some of your code below.

--Mary

On May 7, 2010, at 4:40 AM, Sabeerali(sebi) wrote:

> I am paneling 4 plots....(/2,2/)...First two plots is having longitude varies from 30E to 90W and Last two plots is having longitude from 30E to 150E..Both is having latitude varies from -30 to 30. So the first two plots is having heights less compared to last two plots...I want to increase the height of first to plots and make similar to last two. I used res1@vpWidthF= 0.60 and res1@vpHeightF = 0.80 ..But at this time it is not working...It doesn't make any difference even if we use different values..
>
>
> Any help would be appreciated...
> Thanks....
>
>
>
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
> begin
> ;**************************************************************
>
> in1=addfile("atm1.nc","r")
> in2=addfile("atm2.nc","r")
> in3=addfile("atm3.nc","r")
> in4=addfile("atm4.nc","r")
>
> var1=in1->com
> var1_sig=in1->com_sig
>
> var2=in2->com
> var2_sig=in2->com_sig
>
> var3=in3->com
> var3_sig=in3->com_sig
>
> var4=in4->com
> var4_sig=in4->com_sig
> ;===============================================================================
> plot=new(4,graphic)
> wks=gsn_open_wks("eps","test")
> gsn_define_colormap(wks,"BlueRed")
>
> res1 = True
> res1@vpWidthF = 0.60
> res1@vpHeightF = 0.80
>
> res1@gsnDraw = False
> res1@gsnFrame = False
> res1@cnFillOn=True
> res1@gsnSpreadColors = True
> res1@mpCenterLonF=180
> res1@mpMinLonF=30
> res1@mpMaxLonF=270
> res1@mpMinLatF=-30
> res1@mpMaxLatF=30
>
> res2=True
> res2@gsnDraw = False
> res2@gsnFrame = False
>
> res2@cnLineLabelsOn = False
> res2@gsnContourNegLineDashPattern = 2
>
>
> cntr0=gsn_csm_contour(wks,var1,res2)
> base0=gsn_csm_contour_map_ce(wks,var1_sig,res1) ; lon from 30E to 90W
> overlay(base0,cntr0)
> plot(0)=base0
>
> cntr1=gsn_csm_contour(wks,var2,res2)
> base1=gsn_csm_contour_map_ce(wks,var2_sig,res1)
> overlay(base1,cntr1)
> plot(1)=base1
>
> res1@mpMinLonF=30
> res1@mpMaxLonF=150
> res1@mpMinLatF=-30
> res1@mpMaxLatF=30
>
>
> cntr2=gsn_csm_contour(wks,var3,res2)
> base2=gsn_csm_contour_map_ce(wks,var3_sig,res1) ; lon from 30E to 150E
> overlay(base2,cntr2)
> plot(2)=base2
>
> cntr3=gsn_csm_contour(wks,var4,res2)
> base3=gsn_csm_contour_map_ce(wks,var4_sig,res1)
> overlay(base3,cntr3)
> plot(3)=base3
>
> ;======================================================================
> resP = True
> ;resP@gsnPanelDebug=True
> gsn_panel(wks,plot,(/2,2/),resP)
> end
>
> --
> **********************************
> Sabeerali
> Climate and Global Modeling Division
> Indian Institute of Tropical Meteorology
> Pashan, Pune, 411 008
> ****************************************
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk

_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Fri May 7 09:37:20 2010