Hi Juliane,
Looking again at your query, I think my post from earlier will not help
you. The correct procedure for creating your own marker index and using
that new marker can be seen in the following example that was forwarded
to me:
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
begin
wks = gsn_open_wks("x11","polyg") ; Open a workstation and
mpres = True
mpres@gsnMaximize = True ; Maximize plot in frame.
mpres@gsnFrame = False ; Don't advance the frame
mpres@gsnDraw = False ; Don't advance the frame
map = gsn_csm_map(wks,mpres)
mstrings = (/"Z","x"/)
fontnums = (/37,1/)
xoffset = 0.0
yoffset = (/0.075,0.0/)
ratio = (/1.3125,1.0/)
sizes = (/1.5,1.4/)
angle = 0.0
new_indexes = NhlNewMarker(wks, mstrings, fontnums, xoffset, yoffset, \
ratio, sizes, angle)
gsres = True
gsres@gsMarkerIndex = new_indexes(0)
gsres@gsMarkerColor = "red"
gsres@gsMarkerThicknessF = 10.
dum1 = gsn_add_polymarker(wks,map,0.,0.,gsres)
gsres@gsMarkerIndex = new_indexes(1)
gsres@gsMarkerColor = "blue"
dum2 = gsn_add_polymarker(wks,map,0.,20.,gsres)
draw(map)
frame(wks)
end
note specifically that gsMarkerIndex needs to be set to new_indexes(0)
or new_indexes(1). If you are following this procedure correctly, are
you receiving any error messages?
Adam
On 07/20/2010 08:51 AM, Juliane Otto wrote:
> Hello NCL-people,
>
> I have a problem using polymarkers. They get displayed where I want them
> but the wrong marker (symbol) gets displayed. I have tried both using the
> pre-defined markers e.g.
> gres@gsMarkerIndex = 14 ; new_indexes(1)
>
> and creating my own. e.g.
> mstrings = (/"Z","x"/)
> fontnums = (/37,1/)
> xoffset = 0.0
> yoffset = (/0.075,0.0/)
> ratio = (/1.3125,1.0/)
> sizes = (/1.5,1.4/)
> angle = 0.0
>
> new_indexes = NhlNewMarker(wks, mstrings, fontnums, xoffset, yoffset,
> ratio, sizes, angle)
>
> I think the problem has to do with the font tables. All font tables that I
> want to use lie under the NCARG_ROOT, but it seems like just the default
> font table is being recognised.
> Does anyone know how to sort out this problem?
> I am using ncl-5.1.1.
>
> Thanks a lot in advance
> Juliane
>
>
>
>
>
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk
-- __________________________________________________ Adam Phillips asphilli@ucar.edu National Center for Atmospheric Research tel: (303) 497-1726 Climate and Global Dynamics Division fax: (303) 497-1333 P.O. Box 3000 Boulder, CO 80307-3000 http://www.cgd.ucar.edu/cas/asphilli _______________________________________________ ncl-talk mailing list List instructions, subscriber options, unsubscribe: http://mailman.ucar.edu/mailman/listinfo/ncl-talkReceived on Tue Jul 20 13:43:36 2010
This archive was generated by hypermail 2.1.8 : Wed Jul 28 2010 - 10:42:06 MDT