Re: font size problem

The cnLowLabelFontHeightF and cnHighLabelFontHeightF resources seem to work if I set them both to the same values, so you might try this in your script.

This seems like a bug, so I'll file a report.

--Mary

On Jan 17, 2012, at 2:54 PM, Adam Phillips wrote:

> Hi Alexander,
> I can answer your 2nd and 3rd questions. Someone else will have to answer as to why you cannot alter the size of the H/L labels.
>
> 2) Instead of setting lbOrientation in your mpres list, try setting it in your opts resource list, as that is where you create your color-filled plot.
>
> 3) What text specifically are you referring to? If you are referring to the subtitles, then gsnStringFontHeightF in your opts resource list should work. (I don't believe setting it in the mpres resource will work.) If you want the latitude/longitude labels to be bigger try setting mpres@txFontHeightF = 0.03 and see if that changes them. Otherwise I would try setting mpres@tmXBLabelFontHeightF = 0.020 and mpres@tmYLLabelFontHeightF = 0.20
>
> Let ncl-talk know if my answers to 2) and 3) don't work out.
> Good luck,
> Adam
>
> On 01/17/2012 02:17 PM, Alexander Semenov wrote:
>>
>> Hello!
>>
>> I have a problem with label height font! I want "L" and "H" (for low and high pressure) have bigger font, more visible. I put "cnLowLabelFontHeightF = 0.04" operator but nothing changes. I tried putting 0.4 and different values, the font size stays the same as before. Do you mind telling me what's going on?
>>
>> Second question is that the label bar stays the same place as before even if specified that I want it vertical. What's wrong?
>>
>> Third question is on the size of the font of everyhting outside of the map. It doesn't change?!
>>
>> Third
>>
>> I run ncl/6.0.0
>>
>>
>> ; Example script to produce plots for a WRF real-data run,
>> ; with the ARW coordinate dynamics option.
>>
>> load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
>> load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"
>> ;load "WRFUserARW.ncl"
>>
>> begin
>>
>> a = addfile("/import/wrkdir1/asemenov/WRF/WRFV3/10_25.03_res_30_10km/wrfout_d02_2011-03-10_00:00:00"+".nc", "r")
>>
>> type = "x11"
>>
>> wks = gsn_open_wks(type,"plt_Surface1")
>> gsn_define_colormap(wks,"temp_diff_18lev")
>>
>> ARWres = True
>>
>> times = wrf_user_list_times(a) ; get times in the file
>> ntimes = dimsizes(times) ; number of times in the file
>>
>> ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
>>
>> do it = 0,ntimes-1,2 ; TIME LOOP
>>
>> print("Working on time: " + times(it) )
>> ARWres@TimeLabel = times(it) ; Set Valid time to use on plots
>>
>> mpres = True ; Create map background
>> mpres@mpProjection = "Stereographic"
>> mpres@mpLimitMode = "Corners"
>> mpres@mpMinLatF = 60
>> mpres@mpCenterLatF = 90
>> mpres@mpCenterLonF = -180
>> mpres@mpGridLineDashPattern = 2
>> mpres@mpGeophysicalLineColor = "Black"
>> mpres@mpGeophysicalLineThicknessF = 1.5
>> mpres@mpNationalLineColor = "Black"
>> mpres@mpNationalLineThicknessF = 1.5
>> mpres@mpUSStateLineColor = "Black"
>> mpres@mpUSStateLineThicknessF = 1.5
>> mpres@mpPerimLineColor = "Black"
>> mpres@mpDataBaseVersion = "MediumRes"
>> mpres@mpFillOn = False
>> mpres@gsnStringFontHeightF = 0.045
>> mpres@cnInfoLabelOn = False
>> mpres@lbOrientation = "vertical"
>>
>> map = wrf_map(wks,a,mpres)
>>
>> ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
>> ; First get the variables we will need
>>
>> slp = wrf_user_getvar(a,"slp",it) ; slp
>> wrf_smooth_2d( slp, 3 ) ; smooth slp
>> if ( it .eq. 0 ) then
>> tc = wrf_user_getvar(a,"tc",it) ; 3D tc
>> u = wrf_user_getvar(a,"ua",it) ; 3D U at mass points
>> v = wrf_user_getvar(a,"va",it) ; 3D V at mass points
>> tc2 = tc(0,:,:) ; Use lowest T at time zero
>> else
>> tc2 = wrf_user_getvar(a,"T2",it) ; T2 in Kelvin
>> tc2 = tc2-273.16 ; T2 in C
>>
>> end if
>>
>> tc2@description = "Surface Temperature"
>> tc2@units = "C"
>> ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
>>
>> ; Plotting options for T
>> opts = ARWres
>> opts@cnFillOn = True
>> opts@ContourParameters = (/ -50., 25., 5./)
>> opts@gsnSpreadColorEnd = -3 ; End third from the last color in color map
>> contour_tc = wrf_contour(a,wks,tc2,opts)
>> delete(opts)
>>
>> ; Plotting options for SLP
>> opts = ARWres
>> opts@cnLineColor = "Black"
>> opts@cnHighLabelsOn = True
>> opts@cnLowLabelsOn = True
>> opts@cnLowLabelFontHeightF = 0.04
>> opts@ContourParameters = (/ 940., 1044., 4. /)
>> opts@cnLineLabelsOn = True
>> opts@cnLineLabelPerimOn = True
>> opts@cnLineLabelBackgroundColor = 0.
>> opts@cnLineLabelFontHeightF = 0.015
>> opts@cnInfoLabelOn = False ; turn off info label
>> opts@cnLevelSpacingF = 0.1 ; set contour spacing
>> opts@gsnCenterString = "Default Line Label Settings"
>> opts@cnLineLabelDensityF = 1.5 ; increase the number of line labels/line
>> opts@cnLineLabelInterval = 2 ; labels for every line (default=2)
>> opts@cnLabelMasking = True ; do not draw labels over contour
>> opts@gsnCenterString = "Label Masking"
>> opts@gsnContourLineThicknessesScale = 1.0
>>
>> contour_psl = wrf_contour(a,wks,slp,opts)
>> delete(opts)
>>
>> ; MAKE PLOTS
>> wrf_map_overlay(wks,map,(/contour_tc,contour_psl/),True)
>>
>> ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
>>
>> end do ; END OF TIME LOOP
>>
>> end
>>
>>
>> --
>> regards
>>
>> *******************************************************
>> Alexander Semenov
>> PhD Student - Research Assistant
>> International Arctic Research Center
>> Department of atmospheric sciences
>> University of Alaska Fairbanks
>>
>>
>>
>> _______________________________________________
>> ncl-talk mailing list
>> List instructions, subscriber options, unsubscribe:
>> http://mailman.ucar.edu/mailman/listinfo/ncl-talk
>
> --
> ______________________________________________________________
> Adam Phillips asphilli@ucar.edu
> NCAR/Climate and Global Dynamics Division (303) 497-1726
> P.O. Box 3000
> Boulder, CO 80307-3000 http://www.cgd.ucar.edu/cas/asphilli
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk

_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Wed Jan 18 09:17:07 2012