Re: Is gsn_csm_contour_map_ce overlay impossible?

Hi Nicole,

You can't overlay a map on a map.

You can only overlay contour/vector/streamline/XY plots on a map,
or contour/vector/streamline/XY plots on other contour/vector/streamline/XY plots.

Since you want to overlay plot2 on plot1, my recommendation is to make plot2 a contour plot:

> plot2= gsn_csm_contour(wks,scr({55:62},{-143:-127}), res)

You will get some warning messages when you do this, because "res"
contains some map resources, but that should be okay.

If you don't like the warnings, then create a new resource list:

  res = True ; plot mods desired
  res@gsnDraw = False
  res@gsnFrame = False
  res@cnFillOn = True ; turn on color fill
  res@cnFillMode = "RasterFill"
  res@cnLinesOn = False ; turn of contour lines
  res@cnLevelSpacingF = 1. ; contour spacing
  res@gsnSpreadColors = True ; use full range of color map
  res@lbLabelStride = 4
  res@gsnAddCyclic = False ; data already has cyclic point
   
  mpres = res ; make a copy and then set some map resources

  mpres@mpMinLatF = 55. ; range to zoom in on
  mpres@mpMaxLatF = 62.
  mpres@mpMinLonF =-143.
  mpres@mpMaxLonF =-127.
  mpres@mpDataBaseVersion = "HighRes"
  mpres@pmTickMarkDisplayMode = "Always"; use NCL default lat/lon labels

  plot1= gsn_csm_contour_map_ce(wks,refhalfdeg({55:62},{-143:-127}), mpres)
  plot2= gsn_csm_contour(wks,scr({55:62},{-143:-127}), res)
  overlay(plot1,plot2)
  draw(plot1)
  frame(wks)

You can see some overlay examples at:

http://www.ncl.ucar.edu/Applications/overlay.shtml

In particular, look at the "conOncon_5.ncl" example, which does a similar thing. Or the "conOncon_9.ncl" example.

--Mary

On Aug 16, 2013, at 11:51 AM, Nicole Mölders wrote:

> Dear Lady and Sir,
>
> I want to do an overlay plot with gsn_csm_contour_map_ce. I get the
> message that this plot group does not allow overlay. I use 5.1.1. Is
> this true or do I do s.th. wrong?
> various statements and setting of workstation
> res = True ; plot mods desired
> res@gsnDraw = False
> res@gsnFrame = False
> res@cnFillOn = True ; turn on color fill
> res@cnFillMode = "RasterFill"
> res@cnLinesOn = False ; turn of contour lines
> res@cnLevelSpacingF = 1. ; contour spacing
> res@gsnSpreadColors = True ; use full range of color map
> res@lbLabelStride = 4
> res@pmTickMarkDisplayMode = "Always"; use NCL default lat/lon labels
> res@gsnAddCyclic = False ; data already has cyclic point
> res@mpMinLatF = 55. ; range to zoom in on
> res@mpMaxLatF = 62.
> res@mpMinLonF =-143.
> res@mpMaxLonF =-127.
> res@mpDataBaseVersion = "HighRes"
> plot1= gsn_csm_contour_map_ce(wks,refhalfdeg({55:62},{-143:-127}), res)
> plot2= gsn_csm_contour_map_ce(wks,scr({55:62},{-143:-127}), res)
> overlay(plot1,plot2)
> draw(plot1)
> frame(wks)
> delete(plot1)
> delete(plot2)
> delete(res)
> Thank you very much for letting me know
>
>
>
> --
> Dr. habil. rer. nat. Nicole Mölders, PhD
> aka Carmen N. Moelders
>
> Professor of Atmospheric Sciences
> Founding chair of the Department of Atmospheric Sciences
> Editor-in-Chief of Climate
>
> University of Alaska Fairbanks
> Geophysical Institute & College of Natural Science and Mathematics
> Department of Atmospheric Sciences
> 903 Koyukuk Drive
> Fairbanks, AK 99775-7320, USA
>
> Phone: +1 907 474 7910
> Fax: +1 907 474 7290
> URL: http://www.gi.alaska.edu/~molders, http://www.mdpi.com/journal/climate
> Email: molders@gi.alaska.edu
>
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk

_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Fri Aug 16 12:06:20 2013