Re: MJO clivar

[1] There is no function to calculate the propagation speed
     of the MJO.

[2] "...compare the result with another method/result".
     Not sure what other method you are referring to.
     It would be a surprise if the other method differed in any
     substantive way with that in MJO_CLIVAR.

[3] There are assorted examples on the Application pages
     that can be used as a basis for what you need. In paarticular,
     Example 2 on the MJO Application page
        http://www.ncl.ucar.edu/Applications/mjoclivar.shtml

     Please read the documentation of the assorted functions
     and syntax ( {...} )used.

     Many climate/anomaly functions are at:
     http://www.ncl.ucar.edu/Document/Functions/climo.shtml

[4] The following is an excerpt and modification of example 2,
     Note the use of addfiles and the {...}/ $...$ syntax

   load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"

   var = "uwnd"
   ymdStrt = 19800101 ; start yyyymmdd
   ymdLast = 20111231 ; last
   yrStrt = ymdStrt/10000
   yrLast = ymdLast/10000

   diri = "./"
   fils = systemfunc("ls " + diri + "uwnd*")
   print(fils) ; full path to files

   latS = -10 ; if desired, specify a region and level
   latN = 10
   lonL = 90
   lonR = 270

   lev = 200 ; desired level

   f = addfiles( diri+fils, "r")

   time = f[:]->time ; all times on files
   ymd = cd_calendar(time, -2) ; yyyymmdd
   iStrt = ind(ymd.eq.ymdStrt) ; index start
   iLast = ind(ymd.eq.ymdLast) ; index last
   delete([/time, ymd/])

;***********************************************************
; Read user specified time; create required yyyyddd
;***********************************************************
    time = f->time(iStrt:iLast) ; time:units = "hours since"
    TIME = cd_calendar(time, 0) ; type float
    year = floattointeger( TIME(:,0) )
    month = floattointeger( TIME(:,1) )
    day = floattointeger( TIME(:,2) )
    ddd = day_of_year(year, month, day)
    yyyyddd = year*1000 + ddd ; needed for input

   x = short2flt(f[:]->$var$(iStrt:iLast,{lev},{latS:latN},{lonL:lonR}))
   printVarSummary(x) ; (time,lat,lon)

   xClm = clmDayTLL(x) ; (366,lat,lon)
   xAnom= calcDayAnomTLL ( x, xClm)

   printVarSummary(xClm)
   prntVarSummary(x, uClm)

The 'xAnom' would be uwnd.day.200.anomalies.1980-2011.nc
   or
      var+".day."+lev+".anomalies."+yrStrt+"-"+yrLast+".nc"

The netCDF can be created analogous to Example 2

On 5/16/12 5:44 AM, juki juki wrote:
> Dear All;
>
> I need to make the MJO clivar from 1980-2010 data (OLR). I read the
> following link to do it
> (http://www.ncl.ucar.edu/Applications/Scripts/mjoclivar_14.ncl).
> However, there are 3 data type in it i.e.,
>
> filolr = "olr.day.anomalies.1980-2005.nc <http://olr.day.anomalies.1980-2005.nc/>"
> filu200 = "uwnd.day.200.anomalies.1980-2005.nc <http://uwnd.day.200.anomalies.1980-2005.nc/>"
> filu850 = "uwnd.day.850.anomalies.1980-2005.nc <http://uwnd.day.850.anomalies.1980-2005.nc/>"
>
>
> For filolr I can produce it because the daily olr data already in one file, but for"uwnd.day.200.anomalies.1980-2005.nc", I think uwnd daily data is one file/year (http://www.esrl.noaa.gov/psd/cgi-bin/db_search/DBListFiles.pl?did=59&tid=32778&vid=1524). Probably any body has suggestion to read many file sequently and then produce"uwnd.day.200.anomalies.1980-2005.nc".
>
> Another question, is it any ncl tool to calculate the propagation speed of MJO ? Currently
> I am working with the tracking of MJO propagation. It is worthwhile to compare the result with another method/result.
>
>
> Thanks for sharing,
>
>
> JuKY
>
>
>
> _______________________________________________
> ncl-talk mailing list
> List instructions, subscriber options, unsubscribe:
> http://mailman.ucar.edu/mailman/listinfo/ncl-talk
_______________________________________________
ncl-talk mailing list
List instructions, subscriber options, unsubscribe:
http://mailman.ucar.edu/mailman/listinfo/ncl-talk
Received on Wed May 16 19:16:22 2012