NCL Home > Documentation > Functions > Meteorology

rigrad_bruntv_atm

Compute the atmospheric gradient Richardson number and, optionally, the Brunt-Vaisala, buoyancy and shear.

Available in version 6.4.0 and later.

Prototype

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"  ; This library is automatically loaded
                                                             ; from NCL V6.2.0 onward.
                                                             ; No need for user to explicitly load.

	function rigrad_bruntv_atm (
		thv     : numeric,  ; float, double, integer only
		u       : numeric,  
		v       : numeric,  
		z       : numeric,  
		opt [1] : integer,  
		dim [1] : integer   
	)

	return_val [dimsizes(z)] :  float or double

Arguments

thv

Virtual potential temperature (K): thv = theta*(1+0.61w) where w is the dimensionless mixing ratio. Potential temperature could also be used if the mixing ratio (kg/kg) is not available.

Zonal wind (m/s). Same dimensionality as thv.

Meridional wind (m/s). Same dimensionality as thv.

Geometric height (m). Same dimensionality as thv.

opt

opt=0, Return only the gradient Richardson number as a regular variable.
opt=1, Return only the Brunt-Vaisala frequency as a regular variable.
opt=2, Return the gradient Richardson number and the Brunt-Vaisala frequency as elements of a list variable
opt=3, Return the gradient Richardson number, the Brunt-Vaisala frequency, the buoyancy (1/s) and the wind sheared squared as elements of a list variable

dim

The dimension of thv which corresponds to z.

Return value

A multi-dimensional array of the same size and shape as thv. The output will be double if thv is of type double.

Description

The gradient richardson number (Ri) is a dimensionless ratio. It is related to the buoyant production or consumption of turbulence divided by the shear production of turbulence. It is a criterion for assessing the stability of stratified shear flow. The atmospheric condition is favorable for the occurrence of turbulence when Ri < the critical Richardson number (=0.25). Ri is 'useful' within or near the boundary layer.


 AMS Glossary:
 BruntV: http://glossary.ametsoc.org/wiki/Brunt-v%C3%A4is%C3%A4l%C3%A4_frequency
 Ri_Num: http://glossary.ametsoc.org/wiki/Gradient_richardson_number
         The latter uses Tv and not THETAv in denominator. This is an approximation
         used by boundary layer people where Tv ~ theta,

         http://en.wikipedia.org/wiki/Richardson_number

         P.W. CHan: http://dx.doi.org/10.1088/1755-1307/1/1/012043

 Gradient Richardson Number: RI  = buoyancy/shear_flow
      A dimensionless ratio, Ri, related to the buoyant production or
      consumption of turbulence divided by the shear production of turbulence.
      It is used to indicate dynamic stability and the formation of turbulence.
      The critical Richardson number, Ric, is about 0.25 (although reported values have
      ranged from roughly 0.2 to 1.0), and flow is dynamically unstable and turbulent
      when Ri < Ric. Such turbulence happens either when the wind shear is great enough
      to overpower any stabilizing buoyant forces (numerator is positive), or when there
      is static instability (numerator is negative).

      If the Richardson number is much less than unity, buoyancy is unimportant in the flow.
      If it is much greater than unity, buoyancy is dominant (in the sense that there is
      insufficient kinetic energy to homogenize the fluids).

      Large values of Ri indicate very stable conditions while low values *may*
      indicate dynamic stability (subcritical region).

Brunt-Vaisala:
      The Brunt-Vaisala (BV) frequency at which a displaced air parcel will oscillate when 
      displaced vertically within a statically stable environment. Hence, it should 
      always be positive.  However, this function will return a negative value 
      when the vertical gradient of thv is negative. This is done for informational
      purposes only.  The user can force only positive values via
               
         BV = where(BV.lt.0, 0, BV)

Examples

Example 1: Read data from a WRF file and calculate assorted quantities.

;----------------------------------------------------------
;                     WRF DATA
;----------------------------------------------------------

   a  = addfile("wrfout_d01_2013-05-17_12","r")  ;[Time|1]x[bottom_top|40]x[south_north|324]x[west_east|414]
                                                ;    0            1              2              3

   q  = a->QVAPOR                          ; mixing ratio (kg/kg)
   q  = where(q.lt.0, 0, q)              ; ensure no negative mixing ratios
   printVarSummary(q)                    ; (Time, bottom_top, south_north, west_east)  
   printMinMax(q,0)

   th = wrf_user_getvar(a,"theta",-1)    ; potential temperature (degK)
   th = th*(1.0 + 0.61*q)                                   ; virtual potential temperature
   th@long_name = "virtual potential temperature"

   z  = wrf_user_getvar(a,"z",-1)          ; model height
   ua = wrf_user_getvar(a,"ua"   ,-1)      ; u at mass grid points
   va = wrf_user_getvar(a,"va"   ,-1)      ; v at mass grid points

 ;;Ri   = rigrad_bruntv_atm(th, ua, va, z, 0, 1 ) 
 ;;BV   = rigrad_bruntv_atm(th, ua, va, z, 1, 1 ) 
 ;;RiBV = rigrad_bruntv_atm(th, ua, va, z, 2, 1 ) 
   All  = rigrad_bruntv_atm(th, ua, va, z, 3, 1 ) 

   Ri   = All[0]     ; explicitly extract from list variable  for convenience
   BV   = All[1]     ; must use 'list' syntax  [...]
   BUOY = All[2]
   SHR2 = All[3]
   delete(All)       ; no longer needed

   printVarSummary(Ri)
   printMinMax(Ri,0)
   print("-----------------------------------------")

; print for arbitrarily chosen grid point

   pr = wrf_user_getvar(a, "pressure", -1)   ; for printing purposes only
   ix = 20        ; arbitrary
   jy = 21
   nt = 0


   p  = wrf_user_getvar(a, "pressure", -1)   ; for printing purposes only

   print( sprintf("%7.1f" ,    p(nt,:,jy,ix)) \
        + sprintf("%9.1f" ,    z(nt,:,jy,ix)) \
        + sprintf("%7.1f" ,   th(nt,:,jy,ix)) \
        + sprintf("%15.5e",   Ri(nt,:,jy,ix)) \
        + sprintf("%15.5e", BUOY(nt,:,jy,ix)) \
        + sprintf("%15.5e", SHR2(nt,:,jy,ix)) )

All input variables are 4D with dimensions:

 

    [Time | 1] x [bottom_top | 39] x [south_north | 324] x [west_east | 414]

The (edited) output is: