NCL Home > Documentation > Functions > Meteorology, Crop

actvpr_rhmean_fao56

Compute actual vapor pressure via equation 19 as described in FAO 56.

Available in version 6.4.0 and later.

Prototype

```load "\$NCARG_ROOT/lib/ncarg/nclscripts/csm/crop.ncl"  ; This library is automatically loaded
; from NCL V6.5.0 onward.
; No need for user to explicitly load.

function actvpr_rhmean_fao56 (
tmin       : numeric,
tmax       : numeric,
rhmean     : numeric,
iounit [2] : integer
)
```

Arguments

tmin

An array of any dimensionality containing minimum temperatures.

tmax

An array of any dimensionality containing maximum temperatures. Must be the same size and shape as tmin and rhmean.

rhmean

An array of any dimensionality containing relative humidity values. Must be the same size and shape as tmin and tmax.

iounit

A integer array indicating the units of the input tmin and tmax and returned actvpr variable.

• iounit(0)=0 means the input are in degrees C (degC);
• iounit(0)=1 means the input are in degrees K (degK);
• iounit(0)=2 means the input are in degrees F.

• iounit(1)=0 returns units hPa
• iounit(1)=1 returns units Pa
• iounit(1)=2 returns units kPa

If iounit(0)=1 or 2, the tmin and tmax will be converted to degC internally prior to the computations. The input tmin and tmax are unaltered.

Return value

An array with the same dimensionality and type as tmin containing actual vapor pressure (kPa).

Description

Compute actual vapor pressure (kPa) as described in the Food and Agriculture Organization (FAO) Irrigation and Drainage Paper 56 entitled: Crop evapotranspiration - Guidelines for computing crop water requirement. Specifically, see equation 19 of Chapter 3.

Actual evapotranspiration (here, 'actvpr') is the quantity of water that is actually removed from a surface due to the processes of evaporation and transpiration.

Examples

Example 1: Replicate example 5 in Chapter 3. Here tunit=0.

```  tmin   = 18.0               ; degC
tmax   = 25.0
rhmin  = 54.0               ; %
rhmax  = 82.0
rhmean = (rhmin+rhmax)*0.5
; tunit=0 , degC
actvpr_rhmean = actvpr_rhmean_fao56(tmin, tmax, rhmean, (/0,2/))   ; 1.7788

printVarSummary(actvpr_rhmean)

```
The output for 'actvpr_rhmean' is

```     Variable: actvpr_rhmean
Type: float
Total Size: 4 bytes
1 values
Number of Dimensions: 1
Dimensions and sizes:   [1]
Coordinates:
Number Of Attributes: 4
long_rhmean_name :    actual vapor pressure
units :       kPa
url : http://www.fao.org/docrep/X0490E/x0490e07.htm
info :        FAO 56; EQN 19: min/max t; mean rh
```

Example 1a: Same as Example 1 but the input tmin and tmax are in degK. Here tunit=1.

```  tmin   = 18.0+273.16                  ; degK
tmax   = 25.0+273.16
; tunit=1 , degK
actvpr_rhmean = actvpr_rhmean_fao56(tmin, tmax, rhmean, (/1,2/))   ; 1.7788
```

Example 1b: Same as Example 1 but the input tmin and tmax are in degrees farenheit. Here tunit=2.

```  tmin   = 1.8*18.0 + 32                ; deg Farenheit
tmax   = 1.8*25.0 + 32
; tunit=2 , deg Farenheit
actvpr_rhmean = actvpr_rhmean_fao56(tmin, tmax, rhmean, (/2,2/))   ; 1.7788
```

Example 2: Consider TMIN(time,lat,lon), TMAX(time,lat,lon) and RHMEAN(time,lat,lon) with sizes (3,73,144) and the temperatures have units of degK. Hence, tunit=1.

```
ACTVPR  = actvpr_rhmean_fao56(TMIN, TMAX, RHMEAN, 1)
printVarSummary(ACTVPR)

```
The output for 'ACTVPR' is
```
Variable: ACTVPR
Type: float
Total Size: 126144 bytes
31536 values
Number of Dimensions: 3
Dimensions and sizes: [time | 3] x [lat | 73] x [lon | 144]
Coordinates:
time: [1..3]
lat: [-90..90]
lon: [ 0..357.5]
Number Of Attributes: 4
long_name : actual vapor pressure
units :     kPa
url :       http://www.fao.org/docrep/X0490E/x0490e07.htm
info :      FAO 56; EQN 19: min/max t; mean rh
```