gsn_contour_shade

Shades contour regions given low and/or high values using colors or patterns.

Prototype

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"

	function gsn_contour_shade (
		plot    [1] : graphic,  
		lowval  [1] : numeric,  
		highval [1] : numeric,  
		opt     [1] : string    
	)

	return_val [1] :  graphic

Arguments

The plot to be modified.

Starting with the first contour less than or equal to lowval, all areas less than that first contour will be shaded with the color or pattern specified in opt@gsnShadeLow. Alternatively, opt@gsnShadeMid can be set, and starting with the first contour greater than or equal to lowval, all areas between that first contour and the last contour less than or equal to highval will be shaded with the color or pattern specified in opt@gsnShadeMid.

Starting with the first contour greater than or equal to highval, all areas greater than that first contour will be shaded with the color or pattern specified in opt@gsnShadeHigh. Alternatively, opt@gsnShadeMid can be set, and starting with the first contour less than or equal to highval, all areas between that first contour and the last contour greater than or equal to lowval will be shaded with the color or pattern specified in opt@gsnShadeMid.

A variable containing a list of special plot resources, attached as attributes.

Return value

plot is returned with the modifications described above.

Description

This function will color or pattern shade regions defined via the arguments lowval and/or highval. The type of shading (color or pattern), the exact colors/patterns, and which of the three possible regions will be shaded (le.lowval, ge.lowval.and.le.highval, ge.highval) are determined by the special resource list attached to opt.

The list of possible resources that can be attached to opt is:

• gsnShadeFillType : can be set to "color" for color fill, or "pattern" for pattern fill. "color" is the default. (This resource is case sensitive, do not capitalize "color" or "pattern".)
• gsnShadeLow : an integer or string (ex. "blue") representing what color/pattern to use when filling areas less than the first contour less than or equal to lowval.
• gsnShadeMid : an integer or string (ex. "blue") representing what color/pattern to use when filling areas greater than the first contour greater than or equal to lowval and less than the first contour less than or equal to highval.
• gsnShadeHigh : an integer or string (ex. "blue") representing what color/patterm to use when filling areas greater than the first contour greater than or equal to highval.

One or more of the following resources must be set: gsnShadeLow, gsnShadeMid, gsnShadeHigh. Otherwise the plot is returned without modifications and a warning message is generated.

Note: The shading will always begin at a contour, and not necessarily at the specified lowval or highval. Check your plot to make sure that the results are what you expected.

See Also

ColorNegDashZeroPosContour, ColorShadeLeGeContour, ShadeGeLeContour, ShadeGtContour, ShadeLtContour, ShadeLtGtContour

Examples

Example 1
For an application example, see:

• Description of coneff_13
  "coneff_13.ncl" (frame 1 | frame 2)

res = True
.......
res@gsnDraw = False
res@gsnFrame = False
plot = gsn_csm_contour_map_ce(wks,data,res)

opt = True
opt@gsnShadeFillType = "color"        ; color is the default
opt@gsnShadeLow = 14                  ; use color index 14
opt@gsnShadeHigh = "red"   
plot = gsn_contour_shade(plot,-5.,10.,opt)
draw(plot)
frame(wks)

plot = gsn_csm_contour_map_ce(wks,data,res)

opt = True
opt@gsnShadeFillType = "pattern"      ; pattern fill
opt@gsnShadeHigh = 2       ; use pattern #2   
plot = gsn_contour_shade(plot,-999.,20.,opt)
draw(plot)
frame(wks)

plot = gsn_csm_contour_map_ce(wks,data,res)

opt = True
opt@gsnShadeFillType = "pattern"      ; pattern fill
opt@gsnShadeMid = 2                   ; use pattern #2   
plot = gsn_contour_shade(plot,5.,10.,opt)
draw(plot)
frame(wks)